ROOM	
	ID 145
	PRIVATE
	NAME "Password Scripts"
	PICT "hcblu.gif"
	PICTURE ID 1 NAME "himbun.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "blank.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Password 1"
		SHOWNAME
		OUTLINE 216,63  290,63  290,91  216,91
		LOC 254,70
		SCRIPT
ON OUTCHAT {
;silence chatstr first so you dont say the password in the room you are going to
{ "" CHATSTR =
;roomnumbergoeshere
86 GOTOROOM
;password goes here
} CHATSTR "pass" == IF
}
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Username Password Script"
		SHOWNAME
		OUTLINE 188,104  336,104  336,134  188,134
		LOC 261,111
		SCRIPT
ON OUTCHAT {
{ "" CHATSTR =
100 GOTOROOM
} CHATSTR "Pass" == "Name" USERNAME == AND IF }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Frodo's Multi Password Script"
		SHOWNAME
		OUTLINE 183,149  346,149  346,176  183,176
		LOC 264,155
		SCRIPT
ON OUTCHAT {
{ "$1" GREPSUB pw =
{ dta =
{ dta 1 GET GOTOROOM
} pw dta 0 GET == IF
}
[ [ "pass1" 999 ] ;just add keywords and room ids as shown here
[ "pass2" 716 ]
[ "pass3" 724 ]
[ "pass4" 114 ] ] FOREACH
} CHATSTR "^(.*)$" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 4
		DONTMOVEHERE
		OUTLINE 79,148  119,148  119,200  79,200
		LOC 93,174
		PICTS 1,0,0 2,0,0 ENDPICTS
		SCRIPT
;use pics with your password script.
ON ENTER { 1 ME SETSPOTSTATELOCAL }
ON SELECT { 0 ME SETSPOTSTATELOCAL
"@100 171 You need to say a password to enter this room." LOCALMSG
}
ON OUTCHAT {
{ "" CHATSTR = 1 ME SETSPOTSTATELOCAL ME DEST GOTOROOM
} CHATSTR "password" == IF
}
ON LEAVE { 1 ME SETSPOTSTATELOCAL }
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 5
		NAME "You can stay if your name is here..."
		SHOWNAME
		OUTLINE 175,191  359,191  359,215  175,215
		LOC 268,196
		SCRIPT
;will send people to another palace if their name isnt on this list.
ON SIGNON {
{ "palace://www.someotherpalace" NETGOTO }
"Tom" USERNAME == NOT
"Dick" USERNAME == NOT AND
"Harry" USERNAME == NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Multiple Passwords for Different Rooms"
		SHOWNAME
		OUTLINE 168,265  371,265  371,287  168,287
		LOC 269,269
		SCRIPT
ON OUTCHAT {
{ "" CHATSTR = 150 GOTOROOM } CHATSTR "PASSWORD" == IF
{ "" CHATSTR = 151 GOTOROOM } CHATSTR "PASSWORD2" == IF
{ "" CHATSTR = 152 GOTOROOM } CHATSTR "PASSWORD"3 == IF
{ "" CHATSTR = 153 GOTOROOM } CHATSTR "PASSWORD4" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		NAME "Password 2 With On Select Message"
		SHOWNAME
		OUTLINE 168,229  362,229  362,251  168,251
		LOC 264,234
		SCRIPT
ON SELECT { "You must say the password to enter this room." LOCALMSG }
ON OUTCHAT {
{ "" CHATSTR =
101 GOTOROOM
} "password" LOWERCASE CHATSTR == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		NAME "You Must Say the Password to Leave this Room"
		SHOWNAME
		OUTLINE 150,302  395,302  395,326  150,326
		LOC 272,307
		SCRIPT
; this code is placed in the gate room
ON SIGNON {
keyroom GLOBAL
goback GLOBAL
{    keyroom GLOBAL
{  103 GOTOROOM } keyroom 0 > IF
} goback DEF
}
; this code is placed in every room including the gate room
; but excepting the password room
ON ENTER { goback GLOBAL goback EXEC }
;this code is place on the password room
ON ENTER { keyroom GLOBAL 1 keyroom =
"Please say the password to leave this room" LOCALMSG
}
ON OUTCHAT { keyroom GLOBAL
{ 0 keyroom = "" CHATSTR = } "password" CHATSTR == IF
}
ON LEAVE { keyroom GLOBAL
{ "You didn't say the password" LOCALMSG
} keyroom  0 > IF
}
		ENDSCRIPT
		ENDSPOT
	ENDROOM