ROOM	
	ID 140
	NAME "Random Ambient Sounds"
	PICT "alistorm.gif"
	ARTIST "Alissa"
	PICTURE ID 1 NAME "arrowl.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 2 NAME "arrowr.gif" TRANSCOLOR 56 ENDPICTURE
	DOOR
		ID 1
		NAME "Random Ambient Sounds"
		SHOWNAME
		SHOWFRAME
		OUTLINE 198,4  317,4  317,24  198,24
		LOC 257,14
		SCRIPT
;~MediaList~;thund1,thund2,thund3,thund4		
ON ENTER { 100 ME SETALARM  "Say s-off to turn ambient sounds off,
say s-on to turn them back on" LOCALMSG }
ON ALARM { 1500 RANDOM howlong = 500 howlong +=
; This will play the sounds with timed intervals of no less that 500 ticks and
; no more that 2000 ticks apart. Changing the values above will alter the timing
[
"thund1"
"thund2"
"thund3"
"thund4"
] list = list LENGTH cnt =
{ list cnt RANDOM GET SOUND howlong ME SETALARM } 0 ME GETSPOTSTATE == IF
}
ON OUTCHAT {
{ 1 ME SETSPOTSTATELOCAL "Ambient Sounds Off" LOGMSG "" CHATSTR = }
CHATSTR "s-off" == IF
{ 0 ME SETSPOTSTATELOCAL 10 ME SETALARM "Ambient Sounds On" LOGMSG "" CHATSTR = }
CHATSTR "s-on" == IF
}
ON LEAVE {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		DEST 138
		OUTLINE 1,1  60,1  60,31  1,31
		LOC 30,16
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 5
		DONTMOVEHERE
		DEST 148
		OUTLINE 441,2  509,2  509,32  441,33
		LOC 475,17
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	ENDROOM