ROOM	
	ID 115
	NAME "SB Party Rm 1"
	PICT "garden1.gif"
	PICTURE ID 2 NAME "arrowl.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 3 NAME "arrowr.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 4 NAME "scpty3bg.gif" TRANSCOLOR 56 ENDPICTURE
	DOOR
		ID 1
		OUTLINE 229,154  255,154  255,171  229,171
		LOC 246,143
		PICTS 4,0,0 ENDPICTS
		SCRIPT
ON ENTER {
"This room contains some scripts to ease birthday party room set up" LOCALMSG
"Type ;help to get instructions for the scripts" LOCALMSG
}
ON OUTCHAT {
{  "$1" grepsub textsave = 0 loop =
{ { "happy birthday" text = text textban = } 0 loop == IF
{ textsave text = text textban = } 1 loop == IF
0 counter =
{ "$2" grepsub text = counter ++ } { text "(.)(.*)" grepstr } while
35 loop * 10 + y = 271 counter 2 / 30 * - x =
{ 15 x -= } counter 2 % IF
{ "tombann" "$1" grepsub & x y addlooseprop
"$2" grepsub textban =  30 x +=  }
{ textban "(.)(.*)" grepstr } while
loop ++
} { loop 2 < } while
"" CHATSTR =
} CHATSTR lowercase ";named (.*)" GREPSTR IF
{ mousepos y = x = y 10 * 38 / c = "" CHATSTR =
"dimthisroomto " c itoa & SAY } CHATSTR ";lights" == IF
{ 0 ME setspotstate } CHATSTR ";propson" == IF
{ 1 ME setspotstate } CHATSTR ";propsoff" == IF
{
";named <name> ...........................to hang birthday banner" LOGMSG
";lights...to control light levels..lights set to mouse height" LOGMSG
";propson................to hang the prop gif over the room " LOGMSG
";propsoff................to remove the prop gif over the room " LOGMSG
"" CHATSTR =
} CHATSTR ";help" == IF
}
ON INCHAT {
{ "$1" grepsub atoi  dimroom } CHATSTR "dimthisroomto (.*)" GREPSTR IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		NAME "Banner Props"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 205,360  281,360  282,381  205,381
		LOC 243,370
		SCRIPT
ON SELECT {
[  902247684 902247692 902247699 902247706 902247860 902247714 902247732 902247738 902247744  ]  SETPROPS
{ [ 927781285 902247756 930775040 902247767 902247774 902247781 902247786 902247792 902247799 ]   SETPROPS
} 200 ALARMEXEC
{ [ 903481350 930776330 902247822 902247830 902247842 902247848 902247854 ] SETPROPS
} 400 ALARMEXEC
}
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		DONTMOVEHERE
		DEST 169
		OUTLINE 3,350  54,350  54,382  2,382
		LOC 28,366
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 6
		DONTMOVEHERE
		DEST 116
		OUTLINE 446,352  507,351  510,381  446,381
		LOC 477,366
		PICTS 3,0,0 ENDPICTS
		ENDDOOR
	ENDROOM